//===============================================================
// Garfield V8.1 Input file for:  
//
//   Vertical Drift Chamber (VDC) Simulation
//   for the Qweak experiment at JLab
//
// => Simulation of the ARRIVAL-TIME-DISTRIBUTION for the n-th 
//    drift electron for a given track (using)
//
//================================================================
// Simplified VDC layout for Garfield
//
// VDC consists of one wire plane and two HV planes.
// Garfield forces us to use this orientation of the VDC since 
// in Garfiled  you can only define a X-RANGE **only** for a XT-PLOT ... 
// (There is no YT-PLOT defined in Garfield)
//
//     |     | / 
//     |  *  |/
//     |     |            |
//     |  * /|          Y |
//     |   / |            |
//     |  *  |            ------> X
//     | /   |        used coordinate system
//     |/ *  |
//     |     |          ------> Gravity vector
//    /|  *  |
//   / |     |
//  /  |  *  |
//
//=================================================================
// 
// Author: Klaus Grimm
//         Department of Physics
//         The College of William and Mary
//         Williamsburg, VA 23185 
//
//  email: grimm@jlab.org
//
//==========================================
// Last Change: 04/02/2004
//==========================================

GLOBAL aiter      = 1000         // Number of tracks for ARRIVAL-TIME-DISTRIBUTION
GLOBAL xstep      =  0.05         // Stepping size in X for tracks (0.05=500um)

GLOBAL tanglemin   = 45.0
GLOBAL tanglemax   = 65.0
GLOBAL tanglestep  =  2.0

GLOBAL tofmin     = 0.0            // Minimal Time of Flight for histograms [us]
GLOBAL tofmax     = 0.3            // Maximum Time of Flight for histograms : 300ns

GLOBAL plane      =  1.3           // distance wire plane to HV plane (13mm)
GLOBAL pitch      =  0.423         // perp. distance between signal wires   (4.23mm)
GLOBAL hpitch     =  0.423*0.5     // half pitch size (half drift region)


// Specify the gas-file to be loaded
Global gas_file     `Ar-C2H6_50-50.gas`
//Global gas_file     `Ar-C2H6_63-37.gas`
//Global gas_file     `Ar-CO2_90-10.gas`


// Delete some result files, otherwise results from different settings/simulations
// will be saved in the same file ...   


//=============================================
& CELL
//=============================================

// Load &CELL definition
 GET vdc_cell.dat

// Gravity points perp. to HV plane = x directection
 GRAVITY  1 0 0

//=============================================
& MAGNETIC
//=============================================

 // at present: no B fieed here
 // whats about the earth B field ?!
 COMPONENTS 0 0 0 GAUSS

//=============================================
& GAS
//=============================================

 // Load existing gas_file, which contains all
 // the gas properties needed for tracking

Call inquire_file(gas_file,exist)
 
If exist Then
   get {gas_file}
 Else
 Say "Gas file doesn't exist, please check"
Endif

 // Plot some gas properties
 // plot-options drift-velocity nodiffusion notownsend
 // opt gas-plot nogas-print

//=============================================
& DRIFT
//=============================================
 
 INTEGRATION-PARAMETERS COMPUTE-IF-INTERPOLATION-FAILS
 
 // Heed takes care of cluster generation, it simulates the ionisation of 
 // the gas molecules by a particle.
 TRACK HEED ...
   NODELTA-ELECTRONS NOTRACE-DELTA-ELECTRONS ... 
   NOMULTIPLE-SCATTERING ...
   NOENERGY-CUT ELECTRON ENERGY 1.165 GeV  

 //Sets the size and view of the drift area
 AREA {-1.1*plane, -1.1*pitch, +1.1*plane, +1.1*pitch}
 
 //Number of drift lines used by x(t) etc.
 LINES 60

 // define area around wire #21 for possible plots
 SELECT 21                   // select center wire


//---------------------
// Open Postscript file
//---------------------
!add meta type PostScript file-name "arrival.ps"
!open meta
!act meta


FOR tangle from {tanglemin} to {tanglemax} STEP {tanglestep} DO

// delete old entries from previous simulations
* %DELETE "ARRIVAL_{angle}deg_S21.dat" .

 //ARRIVAL-TIME-DISTRIBUTION:
 //Computes the arrival time distribution of the n'th electron that 
 //reach electrodes from a series of tracks.
 //A by-product of this calculation is the x(t) relation and an estimate of 
 //the arrival time spread. See XT-PLOT for a comparison with related commands.

Say "Simulating now ARRIVAL-TIME-DISTRIBUTION for angle = {tangle}"

 ARRIVAL-TIME-DISTRIBUTION ELECTRON 1 ...
   TIME-WINDOW {tofmin , tofmax} ...
   STEP X RANGE {0.0 , 1.1*plane} INCREMENT {xstep} ...
   SCAN Y RANGE {-1.1*hpitch , +1.1*hpitch} ...
   ANGLE {tangle} ...
   DIFFUSION ...
   DATASET "ARRIVAL_{tangle}deg_S21.dat" ...
   ITERATIONS {aiter} ...
   PLOT-SELECTED-ELECTRONS 

ENDDO

//----------------------
// Close Postscript file
//----------------------
!deact meta
!close meta
!del   meta