//==========================================
// Garfield V8.1 Input file for:  
//
// Vertical Drift Chamber (VDC) Simulation
// for the Qweak experiment at JLab
//
// => Simulation of the XT-Plot
//    Correlation between perp. track distance to the wire plane and
//    the drift time of the first electron hitting the selected wire 
//
//==========================================
// VDC Realization in Garfield:
//
// VDC consists of one wire plane and two HV planes
// 
//==========================================
// 
// Author: Klaus Grimm
//         Department of Physics
//         The College of William and Mary
//         Williamsburg, VA 23185 
//
//  email: grimm@jlab.org
//
//==========================================
// Last Change: 05/02/2004
//==========================================


GLOBAL tanglemin   = 45.0
GLOBAL tanglemax   = 65.0
GLOBAL tanglestep  =  2.0

GLOBAL xstep       =  0.05        // Stepping size in X for tracks (0.05=500um)

GLOBAL plane      =  1.3           // distance wire plane to HV plane (13mm)
GLOBAL pitch      =  0.423         // perp. distance between signal wires   (4.23mm)
GLOBAL apitch     =  0.423*0.5     // half top   pitch size used for ARRIVAL-TIME-DISTRIBUTION
GLOBAL tpitch     =  apitch*1.41   // bit more than bottom half pitch size used for TIMING

Global gas_file     `Arg-50-Eth-50.gas`
Global gas_member   `a50e50`


// Delete some result files, otherwise results from different settings/simulations
// will be saved in the same file ...   


//=============================================
& CELL
//=============================================

// Read &CELL definition
 READ vdc_cell.dat

// Gravity points perp. to HV plane = x directection
 GRAVITY  1 0 0

//=============================================
& MAGNETIC
//=============================================

 // at present: no B fieed here
 // whats about the earth B field ?!
 COMPONENTS 0 0 0 GAUSS

//=============================================
& GAS
//=============================================

 // 1 atm 50/50 Argon-ethane mixture in your chamber.


// Load (existing) gas_file, which contains all
// the gas properties needed for tracking
   GET {gas_file,gas_member}

// Prepares cluster generation by Heed
   Heed argon 50 ethane 50

// Plot some gas properties
// plot-options drift-velocity nodiffusion notownsend
// opt gas-plot nogas-print

//=============================================
& OPTIMISE
//=============================================

 //Prints the current potential settings
 DISPLAY

 //forces acting on a wire and the wire displacement
 SELECT 21
 FORCES  PRINT-SAG PLOT-SAG KEEP-SAG DETAILED ...
 ELECTROSTATICS GRAVITY

//=============================================
& DRIFT
//=============================================

 INTEGRATION-PARAMETERS COMPUTE-IF-INTERPOLATION-FAILS
 
 // Heed takes care of cluster generation, it simulates the ionisation of 
 // the gas molecules by a particle.
 TRACK HEED ...
   NODELTA-ELECTRONS NOTRACE-DELTA-ELECTRONS ... 
   NOMULTIPLE-SCATTERING ...
   NOENERGY-CUT ELECTRON ENERGY 1.1 GeV  

 //Sets the size and view of the drift area
 AREA {-1.1*plane, -1.0*tpitch, +1.1*plane, +1.0*tpitch}
 
 //Number of drift lines used by x(t) etc.
 LINES 100

 // define area around wire #21 for possible plots
 SELECT 21                   // select center wire
 
//---------------------
// Open Postscript file
//---------------------
!add meta type PostScript file-name "erin_xt.ps"
!open meta
!act meta


FOR tangle from {tanglemin} to {tanglemax} STEP {tanglestep} DO

// delete old entries from previous simulations
* %DELETE "XT_{angle}deg_S21.dat" .

// XT-PLOT: relation between the perp. position of a track and the drift time.
// This is a calibration curve used by the track reconstruction program

Say "Simulating now XT-PLOT for incident angle = {tangle}"

  XT-PLOT ...
    ANGLE {tangle} ...
    X-RANGE {0.0 , 1.1*plane}  X-STEP {xstep} ...
    PRECISION 1E-4 ...
    PLOT-XT-RELATION ...
    DATASET "XT_{tangle}deg_S21.dat" 

ENDDO

//----------------------
// Close Postscript file
//----------------------
!deact meta
!close meta
!del   meta