//==========================================
// Garfield V8.1 Input file for:  
//
// Vertical Drift Chamber (VDC) Simulation
// for the Qweak experiment at JLab
//
// => Time of Flight (TOF) spectrum given by TIMING
//
//================================================================
// Simplified VDC layout for Garfield
//
// VDC consists of one wire plane and two HV planes.
// Garfield forces us to use this orientation of the VDC since 
// in Garfiled  you can only define a X-RANGE **only** for a XT-PLOT ... 
// (There is no YT-PLOT defined in Garfield)
//
//     |     | / 
//     |  *  |/
//     |     |            |
//     |  * /|          Y |
//     |   / |            |
//     |  *  |            ------> X
//     | /   |        used coordinate system
//     |/ *  |
//     |     |          ------> Gravity vector
//    /|  *  |
//   / |     |
//  /  |  *  |
//
//=================================================================
// 
// Author: Klaus Grimm
//         Department of Physics
//         The College of William and Mary
//         Williamsburg, VA 23185 
//
//  email: grimm@jlab.org
//
//==========================================
// Last Change: 05/02/2004
//==========================================

GLOBAL titer      = 10000           // Number of tracks for TIMING

GLOBAL tofmin     = 0.0           // Min. Time of Flight for histograms [us]
GLOBAL tofmax     = 0.3           // Max. Time of Flight for histograms : 300ns

GLOBAL plane      =  1.3           // distance wire plane to HV plane (13mm)
GLOBAL pitch      =  0.423         // perp. distance between signal wires   (4.23mm)
GLOBAL apitch     =  0.423*0.5     // half top   pitch size used for ARRIVAL-TIME-DISTRIBUTION
GLOBAL tpitch     =  apitch*1.41   // bit more than bottom half pitch size used for TIMING

// Hall A VDC tracking angle 
// Source: MIT Thesis of Risa Wechsler, 1999
GLOBAL anglemean  =  54.7          // mean garfield tracking angle = 54.7deg
GLOBAL anglemin   =  53.787        // min  garfield tracking angle = 53.787deg
GLOBAL anglemax   =  55.673        // max  garfield tracking angle = 55.673deg

// Specify the gas-file to be loaded
Global gas_file     `Ar-C2H6_50-50.gas`
//Global gas_file     `Ar-C2H6_63-37.gas`
//Global gas_file     `Ar-CO2_90-10.gas

// Delete some result files, otherwise results from different settings/simulations
// will be saved in the same file ...   


//=============================================
& CELL
//=============================================

// Load &CELL definition
 GET vdc_cell.dat


//=============================================
& MAGNETIC
//=============================================

 // at present: no B fieed here
 // whats about the earth B field ?!
 COMPONENTS 0 0 0 GAUSS

//=============================================
& GAS
//=============================================

// Load gas_file, which contains all
// the gas properties needed for tracking

Call inquire_file(gas_file,exist)
 
If exist Then
   get {gas_file}
 Else
	Say "Gas file doesn't exist, please check"
Endif

// Plot some gas properties
// plot-options drift-velocity nodiffusion notownsend
// opt gas-plot nogas-print

//=============================================
& DRIFT
//=============================================

 
 INTEGRATION-PARAMETERS COMPUTE-IF-INTERPOLATION-FAILS
 
 // Heed takes care of cluster generation, it simulates the ionisation of 
 // the gas molecules by a particle.
 TRACK HEED ...
   NODELTA-ELECTRONS NOTRACE-DELTA-ELECTRONS ... 
   NOMULTIPLE-SCATTERING ...
   NOENERGY-CUT ELECTRON ENERGY 1.165 GeV  

 //Sets the size and view of the drift area
 AREA {-1.1*plane, -1.0*tpitch, +1.1*plane, +1.0*tpitch}
 
 //Number of drift lines used by XT-PLOT and TIMING.
 LINES 200

 // define area around wire #21 for possible plots
 SELECT 21                   // select center wire


//---------------------
// Open Postscript file
//---------------------
!add meta type PostScript file-name "timing.ps"
!open meta
!act meta


// Last but not least (in cpu time comsuming =8-)

 // TIMING:  Computes the arrival time distribution of the n'th electron over 
 // a given area. Unlike the ARRIVAL-TIME-DISTRIBUTION instruction, TIMING does 
 // not produce calibration curves, but merely timing distributions.
 // 
 // -> good for (white noise) TOF spectrum 

Say "Simulating now TOF Spectrum with TIMING"

 TIMING ELECTRON 1 ...
   TIME-WINDOW {tofmin , tofmax} ... 
   X-RANGE {-1.1*plane, 0.0}  ...
   Y-RANGE  {-tpitch , +tpitch} ...
   ANGLE-RANGE {anglemin , anglemax} ...
   BINS 301 ...
   ITERATIONS {titer} ...
   RUNGE-KUTTA-DRIFT ...
   PLOT-SELECTED-ELECTRON 

//----------------------
// Close Postscript file
//----------------------
!deact meta
!close meta
!del   meta